Fixed. ClearChart now uses the current ClassType to call the Create constructor properly.  


Procedure TCustomChart.ClearChart;

  procedure InitChart;
  type
    TCustomChartClass=class of TCustomChart;

  var tmpChart : TCustomChart;
      tmpClass : TCustomChartClass;
  begin
    // Use ClassType to call derived classes Create constructor
    tmpClass:=TCustomChartClass(ClassType);

    tmpChart:=tmpClass.Create(nil);
    try
      tmpChart.Parent:=Parent;
      Assign(tmpChart);
    finally
      tmpChart.Free;
    end;
  end;

var t : Integer;
begin
  for t:=0 to SeriesCount-1 do
    if Assigned(Series[t].Datasource) then
      {$IFDEF TEEOCX}
      {$IFDEF DATABASE}
      if (Series[t].DataSource is TTeeADOQuery) then
         Series[t].Datasource.Free
      else
      {$ENDIF}
      {$ENDIF}
        Series[t].Datasource:=nil;

  FreeAllSeries;
  SeriesList.Clear; //TV52015747
  Tools.Clear;
  Animations.Clear;

  for t:=0 to Axes.Count-1 do
      Axes[t].Items.Clear;

  Axes.Reset;

  InitChart;
end;